Script cdosys
De TeHospedia
O exemplo de script abaixo utiliza o componente cdosys utilizando autenticação no servidor de emails (smtp). Para que o mesmo possa enviar as mensagens, é necessário que uma conta de email seja criada para o propósito de autenticação ou então utilizá-la também para o recebimento das mensagens.
<%session.LCID = 1046%>
<html>
<head>
<title>CDOsys</title>
</head>
<body>
<p align="center"><font face="Arial" size="5">Formulario de E-mail</font></p>
<font face="Arial">
<%
Dim msg, remetente, destinatario, nome, cidade, estado, email, assunto, mensagem, data
remetente = "conta_remetente@seudominio.com.br"
destinatario = "conta_destinatario@dominio.com.br"
nome = Request.Form("nome")
cidade = Request.Form("cidade")
estado = Request.Form("estado")
email = Request.Form("email")
assunto = "Setor: " & Request.Form("assunto")
mensagem = Request.Form("mensagem")
data = now()
Set msg = CreateObject("CDO.Message")
msg.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/sendusing") = 2
msg.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/smtpserver") ="mail.seudominio.com.br"
msg.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/smtpserverport") = 25
msg.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/smtpusessl") = False 'Ativa/Desativa conexao SSL (True ou False)
msg.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/smtpconnectiontimeout") = 60
msg.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/smtpauthenticate") = 1 'Ativa autenticacao em texto plano (clear-text)
msg.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/sendusername") ="conta_remetente@seudominio.com.br"
msg.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/sendpassword") ="senha_do_email"
msg.Configuration.Fields.Update
msg.To = destinatario
msg.Subject = assunto
msg.From = remetente
'msg.HTMLBody = "opcao para ter o corpo de texto em formato html"
msg.TextBody = "IP de Origem: " & Request.ServerVariables("REMOTE_ADDR") & vbcrlf&_
"Data: " & data & vbcrlf&_
"----------------------------" & vbcrlf&_
"Nome: " & nome & vbcrlf&_
"Cidade: " & cidade & vbcrlf&_
"Estado: " & estado & vbcrlf&_
"E-mail: " & email & vbcrlf&_
"Mensagem: " & vbcrlf&_
mensagem & vbcrlf
msg.Send
Set msg = Nothing
%>
</font><center><font face="Arial" size="3">Seu e-mail foi enviado com sucesso<br>
</font></center>
<p align="center"><font face="Arial"><a href="formulario.asp">Retorne ao Formulario</a></font></p>
</body>
</html>
